a8d553218c
Prior to this commit, the Spring Framework build would rely on setting a custom Java HOME for building all sources and tests with that JDK. This approach is not flexible enough, since we would be testing the source compatibility against a recent JDK, but not a common case experienced by the community: compiling and running application code with a recent JDK and the official, JDK8-based Framework artifacts. This method is also limiting our choice of JDKs to the ones currently supported by Gradle itself. This commit introduces the support of Gradle JVM Toolchains in the Spring Framework build. We can now select a specific JDK for compiling the main SourceSets (Java, Groovy and Kotlin) and another one for compiling and running the test SourceSets: `./gradlew check -PmainToolChain=8 -PtestToolchain=15` Gradle will automatically find the JDKs present on the host or download one automcatically. You can find out about the ones installed on your host using: `./gradlew -q javaToolchains` Finally, this commit also refactors the CI infrastructure to: * only have a single CI image (with all the supported JDKs) * use this new feature to compile with JDK8 but test it against JDK11 and JDK15. Closes gh-25787
39 lines
1.2 KiB
Groovy
39 lines
1.2 KiB
Groovy
description = "Spring Beans"
|
|
|
|
apply plugin: "groovy"
|
|
apply plugin: "kotlin"
|
|
|
|
dependencies {
|
|
compile(project(":spring-core"))
|
|
optional("javax.inject:javax.inject")
|
|
optional("org.yaml:snakeyaml")
|
|
optional("org.codehaus.groovy:groovy-xml")
|
|
optional("org.jetbrains.kotlin:kotlin-reflect")
|
|
optional("org.jetbrains.kotlin:kotlin-stdlib")
|
|
testCompile(testFixtures(project(":spring-core")))
|
|
testCompile("javax.annotation:javax.annotation-api")
|
|
testFixturesApi("org.junit.jupiter:junit-jupiter-api")
|
|
testFixturesImplementation("org.assertj:assertj-core")
|
|
}
|
|
|
|
// This module does joint compilation for Java and Groovy code with the compileGroovy task.
|
|
sourceSets {
|
|
main.groovy.srcDirs += "src/main/java"
|
|
main.java.srcDirs = []
|
|
}
|
|
|
|
compileGroovy {
|
|
options.compilerArgs += "-Werror"
|
|
}
|
|
|
|
// This module also builds Kotlin code and the compileKotlin task naturally depends on
|
|
// compileJava. We need to redefine dependencies to break task cycles.
|
|
tasks.named('compileGroovy') {
|
|
// Groovy only needs the declared dependencies (and not the result of Java compilation)
|
|
classpath = sourceSets.main.compileClasspath
|
|
}
|
|
tasks.named('compileKotlin') {
|
|
// Kotlin also depends on the result of Groovy compilation
|
|
classpath += files(sourceSets.main.groovy.classesDirectory)
|
|
}
|