d84ca2ba90
Upgrades many dependency declarations; removes old EJB 2.x support and outdated Servlet-based integrations (Commons FileUpload, FreeMarker JSP support, Tiles). Closes gh-22093 Closes gh-25354 Closes gh-26185 Closes gh-27423 See gh-27424
40 lines
1.3 KiB
Groovy
40 lines
1.3 KiB
Groovy
description = "Spring Beans"
|
|
|
|
apply plugin: "groovy"
|
|
apply plugin: "kotlin"
|
|
|
|
dependencies {
|
|
api(project(":spring-core"))
|
|
optional("jakarta.inject:jakarta.inject-api")
|
|
optional("org.yaml:snakeyaml")
|
|
optional("org.codehaus.groovy:groovy-xml")
|
|
optional("org.jetbrains.kotlin:kotlin-reflect")
|
|
optional("org.jetbrains.kotlin:kotlin-stdlib")
|
|
testImplementation(testFixtures(project(":spring-core")))
|
|
testImplementation("jakarta.annotation:jakarta.annotation-api")
|
|
testFixturesApi("org.junit.jupiter:junit-jupiter-api")
|
|
testFixturesImplementation("org.assertj:assertj-core")
|
|
}
|
|
|
|
// This module does joint compilation for Java and Groovy code with the compileGroovy task.
|
|
sourceSets {
|
|
main.groovy.srcDirs += "src/main/java"
|
|
main.java.srcDirs = []
|
|
}
|
|
|
|
compileGroovy {
|
|
// Groovy generates Java code with "new Boolean" usage which is deprecated on JDK 17
|
|
// options.compilerArgs += "-Werror"
|
|
}
|
|
|
|
// This module also builds Kotlin code and the compileKotlin task naturally depends on
|
|
// compileJava. We need to redefine dependencies to break task cycles.
|
|
tasks.named('compileGroovy') {
|
|
// Groovy only needs the declared dependencies (and not the result of Java compilation)
|
|
classpath = sourceSets.main.compileClasspath
|
|
}
|
|
tasks.named('compileKotlin') {
|
|
// Kotlin also depends on the result of Groovy compilation
|
|
classpath += files(sourceSets.main.groovy.classesDirectory)
|
|
}
|