84f8cfe446
* Spring Data 2023.0.0-RC1 * Spring Security 6.1.0-RC1 * Micrometer 1.11.0-RC1 * Micrometer Tracing 1.1.0-RC1 * Context Propagation 1.1.0-M2 * Jackson 2.15.0-rc3 * GraphQL Java 20.2 * Spring Framework 6.0.8 Closes gh-663 Closes gh-664 Closes gh-665 Closes gh-666 Closes gh-667 Closes gh-668 Closes gh-669 Closes gh-670
59 lines
1.5 KiB
Groovy
59 lines
1.5 KiB
Groovy
description = "Spring for GraphQL"
|
|
|
|
ext {
|
|
moduleProjects = [project(":spring-graphql"), project(":spring-graphql-test")]
|
|
springFrameworkVersion = "6.0.8"
|
|
graphQlJavaVersion = "20.2"
|
|
springBootVersion = "3.1.0-M2"
|
|
}
|
|
|
|
subprojects {
|
|
apply plugin: 'org.springframework.graphql.build.conventions'
|
|
group = 'org.springframework.graphql'
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
if (version.contains('-')) {
|
|
maven { url "https://repo.spring.io/milestone" }
|
|
}
|
|
if (version.endsWith('-SNAPSHOT')) {
|
|
maven { url "https://repo.spring.io/snapshot" }
|
|
}
|
|
}
|
|
}
|
|
|
|
configure(moduleProjects) {
|
|
apply plugin: 'java-library'
|
|
apply plugin: 'java-test-fixtures'
|
|
|
|
java {
|
|
toolchain {
|
|
languageVersion = JavaLanguageVersion.of(17)
|
|
}
|
|
}
|
|
|
|
configurations {
|
|
dependencyManagement {
|
|
canBeConsumed = false
|
|
canBeResolved = false
|
|
visible = false
|
|
}
|
|
matching { it.name.endsWith("Classpath") }.all { it.extendsFrom(dependencyManagement) }
|
|
}
|
|
|
|
dependencies {
|
|
dependencyManagement(enforcedPlatform(dependencies.project(path: ":platform")))
|
|
}
|
|
|
|
ext.javadocLinks = [
|
|
"https://docs.oracle.com/en/java/javase/17/docs/api/",
|
|
"https://docs.spring.io/spring-framework/docs/6.0.x/javadoc-api/",
|
|
"https://javadoc.io/doc/com.graphql-java/graphql-java/20.2/"
|
|
] as String[]
|
|
|
|
components.java.withVariantsFromConfiguration(configurations.testFixturesApiElements) { skip() }
|
|
components.java.withVariantsFromConfiguration(configurations.testFixturesRuntimeElements) { skip() }
|
|
|
|
apply from: "${rootDir}/gradle/publishing.gradle"
|
|
}
|