plugins {
	id "io.spring.compatibility-test" version "0.0.1"
	id "java-library"
	id "maven-publish"
}

description = "Spring REST Docs WebFlux"

dependencies {
	api(project(":spring-restdocs-core"))
	api("org.springframework:spring-test")
	api("org.springframework:spring-webflux")

	internal(platform(project(":spring-restdocs-platform")))

	testImplementation(testFixtures(project(":spring-restdocs-core")))
	testImplementation("junit:junit")
	testImplementation("org.assertj:assertj-core")
	testImplementation("org.hamcrest:hamcrest-library")
	testImplementation("org.mockito:mockito-core")

	testRuntimeOnly("org.springframework:spring-context")
	testRuntimeOnly("org.synchronoss.cloud:nio-multipart-parser")
}

compatibilityTest {
	dependency("Spring Framework") { springFramework ->
		springFramework.groupId = "org.springframework"
		springFramework.versions = ["5.1.+", "5.2.+", "5.3.+"]
	}
}

project.afterEvaluate {
	configurations.getByName("testRuntimeClasspath_spring_framework_5.3.+") {
		exclude group: "org.synchronoss.cloud", module: "nio-multipart-parser"
	}	
}
