buildscript {
	dependencies {
		classpath 'io.spring.gradle:spring-build-conventions:0.0.27.RELEASE'
		classpath "org.springframework.boot:spring-boot-gradle-plugin:$springBootVersion"
	}
	repositories {
		gradlePluginPortal()
		maven { url 'https://repo.spring.io/plugins-snapshot' }
	}
}

apply plugin: 'io.spring.convention.root'

allprojects {

	group = 'org.springframework.session'

	repositories {

		mavenCentral()

		if (version.contains('-')) {
			maven { url "https://repo.spring.io/milestone" }
		}
		if (version.endsWith('-SNAPSHOT')) {
			maven { url "https://repo.spring.io/snapshot" }
		}
	}

	configurations.all {
		resolutionStrategy.cacheChangingModulesFor 0, "minutes"
	}
}

if (project.hasProperty('artifactoryUsername')) {
	allprojects { project ->
		project.repositories { repos ->
			all { repo ->
				if (!repo.url.toString().startsWith("https://repo.spring.io/")) {
					return;
				}
				repo.credentials {
					username = artifactoryUsername
					password = artifactoryPassword
				}
			}
		}
	}
}

description = 'Spring Session for Apache Geode'

ext['groovy.version'] = "$groovyVersion"
ext['spring.version'] = "$springVersion"
ext['spring-framework.version'] = "$springVersion"
ext['spring-data-releasetrain.version'] = "$springDataReleaseTrainVersion"
ext['spring-session-bom.version'] = "$springSessionBomVersion"

ext.snapshotBuild = version.endsWith('SNAPSHOT')
ext.releaseBuild = version.endsWith('RELEASE')
ext.milestoneBuild = !(releaseBuild || snapshotBuild)

ext.MAVEN_POM_EDITOR_GRADLE = "$rootDir/gradle/maven-pom-editor.gradle"