plugins {
	// id 'org.asciidoctor.jvm.convert' version '3.2.0'
	// id 'org.asciidoctor.jvm.pdf' version '3.2.0'
}

apply plugin: 'io.spring.convention.docs'
apply plugin: 'io.spring.convention.spring-test'

repositories {
	maven { url "https://repo.spring.io/release" }
}

dependencies {

	testImplementation project(':spring-session-data-geode')
	testImplementation "jakarta.servlet:jakarta.servlet-api"
	testImplementation "org.springframework.security:spring-security-core"
	testImplementation "org.springframework.security:spring-security-test"
	testImplementation "org.springframework.security:spring-security-web"

}

def versions = dependencyManagement.managedVersions

asciidoctor {
	clearSources()
	clearSecondarySources()
	sources {
		include "index.adoc"
		include "guides/*.adoc"
	}
	resources {
		duplicatesStrategy DuplicatesStrategy.EXCLUDE
	}
}

asciidoctorj {

	def ghTag = snapshotBuild ? 'master' : project.version
	def ghUrl = "https://github.com/spring-projects/spring-session-data-geode/tree/$ghTag"

	attributes 'gh-url': ghUrl,
		'gh-samples-url': "$ghUrl/samples/",
		'download-url' : "https://github.com/spring-projects/spring-session-data-geode/archive/${ghTag}.zip",
		'docinfodir@': ".",
		'highlightjsdir@': "js/highlight",
//		'stylesheet' : pathToSpringCss,
		'master-data-store-name' : 'Apache Geode',
		'master-data-store-version' : '112',
//		'spring-version' : "$springVersion",
		'spring-version' : versions['org.springframework:spring-core'],
		'spring-data-commons-version' : "$springDataCommonsVersion",
		'spring-data-geode-version' : "$springDataGeodeVersion",
		'spring-session-core-version' : "$springSessionVersion",
		'spring-session-data-geode-version' : project.version,
		'docs-itest-dir' : rootProject.projectDir.path + '/docs/src/integration-test/java/',
		'docs-test-dir' : rootProject.projectDir.path + '/docs/src/test/java/',
		'docs-test-resources-dir' : rootProject.projectDir.path + '/docs/src/test/resources/',
		'samples-dir' : rootProject.projectDir.path + '/samples/',
		'session-main-resources-dir' : rootProject.projectDir.path + '/spring-session/src/main/resources/',
		'version-snapshot': snapshotBuild,
		'version-milestone': milestoneBuild,
		'version-release': releaseBuild

}

asciidoctorPdf {
	clearSources()
	clearSecondarySources()
	sources {
		include "index.adoc"
		// include "guides/*.adoc"
	}
	resources {
		duplicatesStrategy DuplicatesStrategy.EXCLUDE
	}
}

javadoc {
	configure(options) {
		links = [
			"https://docs.spring.io/spring/docs/current/javadoc-api/",
			"https://docs.spring.io/spring-data/commons/docs/current/api/index.html",
			"https://docs.spring.io/spring-data/geode/docs/current/api/",
			"https://docs.spring.io/spring-session/docs/${springSessionVersion}/api/",
			"https://geode.apache.org/releases/latest/javadoc/index.html",
		]
	}
}