pluginManagement {
	repositories {
		mavenCentral()
		gradlePluginPortal()
		maven {
			url 'https://repo.spring.io/release'
		}
		if (version.endsWith('-SNAPSHOT')) {
			maven { url "https://repo.spring.io/snapshot" }
		}
	}
}

plugins {
	id "com.gradle.enterprise" version "3.11.1"
	id "io.spring.ge.conventions" version "0.0.11"
}

rootProject.name = 'spring-session-data-geode-build'

FileTree buildFiles = fileTree(rootDir) {
	include '**/*.gradle'
	exclude '/build.gradle', 'settings.gradle', '**/gradle', 'buildSrc', '.*'
}

String rootDirPath = rootDir.absolutePath + File.separator

buildFiles.each { File buildFile ->

	boolean isDefaultName = 'build.gradle'.equals(buildFile.name)

	if (isDefaultName) {
		String buildFilePath = buildFile.parentFile.absolutePath
		String projectPath = buildFilePath.replace(rootDirPath, '').replaceAll(File.separator, ':')

		include projectPath
	}
	else {
		String projectName = buildFile.name.replace('.gradle', '');
		String projectPath = ':' + projectName;

		include projectPath

		def project = findProject("${projectPath}")

		project.name = projectName
		project.projectDir = buildFile.parentFile
		project.buildFileName = buildFile.name
	}
}