Add Spring Security Sample

Fixes gh-68

samples/security/src/integration-test/groovy/sample/SecurityTests.groovy

@@ -0,0 +1,50 @@
+package sample
+
+import geb.spock.GebReportingSpec
+import pages.*
+import sample.pages.HomePage
+import sample.pages.LoginPage
+import spock.lang.Stepwise
+
+/**
+ * Ensures that Spring Security and Session are working
+ *
+ * @author Rob Winch
+ */
+@Stepwise
+class SecurityTests extends GebReportingSpec {
+
+    def 'Unauthenticated user sent to log in page'() {
+        when: 'unauthenticated user request protected page'
+        via HomePage
+        then: 'sent to the log in page'
+        at LoginPage
+    }
+
+    def 'Log in views home page'() {
+        when: 'log in successfully'
+        login()
+        then: 'sent to original page'
+        at HomePage
+        and: 'the username is displayed'
+        username == 'user'
+        and: 'Spring Session Management is being used'
+        driver.manage().cookies.find { it.name == 'SESSION' }
+        and: 'Standard Session is NOT being used'
+        !driver.manage().cookies.find { it.name == 'JSESSIONID' }
+    }
+
+    def 'Log out success'() {
+        when:
+        logout()
+        then:
+        at LoginPage
+    }
+
+    def 'Logged out user sent to log in page'() {
+        when: 'logged out user request protected page'
+        via HomePage
+        then: 'sent to the log in page'
+        at LoginPage
+    }
+}

samples/security/src/integration-test/groovy/sample/pages/HomePage.groovy

@@ -0,0 +1,17 @@
+package sample.pages
+
+import geb.Page
+
+/**
+ * The home page
+ *
+ * @author Rob Winch
+ */
+class HomePage extends Page {
+    static url = ''
+    static at = { assert driver.title == 'Secured Content'; true}
+    static content = {
+        username { $('#un').text() }
+        logout(to:LoginPage) { $('input[type=submit]').click() }
+    }
+}

samples/security/src/integration-test/groovy/sample/pages/LoginPage.groovy

@@ -0,0 +1,22 @@
+package sample.pages
+
+import geb.Page
+
+/**
+ * The Links Page
+ *
+ * @author Rob Winch
+ */
+class LoginPage extends Page {
+    static url = '/login'
+    static at = { assert driver.title == 'Login Page'; true}
+    static content = {
+        form { $('form') }
+        submit { $('input[type=submit]') }
+        login(required:false) { user='user', pass='password' ->
+            form.username = user
+            form.password = pass
+            submit.click(HomePage)
+        }
+    }
+}