pluginManagement {
    repositories {
        gradlePluginPortal()
        maven { url 'https://repo.spring.io/plugins-release' }
    }
}

plugins {
    id "com.gradle.develocity" version "3.17.6"
    id "io.spring.ge.conventions" version "0.0.17"
}

rootProject.name = 'spring-session-build'

include 'spring-session-dependencies'
include 'spring-session-bom'
include 'spring-session-core'
include 'spring-session-data-mongodb'
include 'spring-session-data-redis'
include 'spring-session-docs'
include 'spring-session-hazelcast'
include 'spring-session-jdbc'

file('spring-session-samples').eachDirMatch(~/spring-session-sample-.*/) { dir ->
    include dir.name
    project(":$dir.name").projectDir = dir
}

rootProject.children.each { project ->
    project.buildFileName = "${project.name}.gradle"
}

