buildscript {
  dependencies {
    classpath 'io.spring.gradle:spring-build-conventions:0.0.38'
    classpath "org.springframework.boot:spring-boot-gradle-plugin:$springBootVersion"
  }
  repositories {
    mavenCentral()
    gradlePluginPortal()
    maven {
      url 'https://repo.spring.io/plugins-snapshot'
      if (project.hasProperty('artifactoryUsername')) {
        credentials {
          username "$artifactoryUsername"
          password "$artifactoryPassword"
        }
      }
    }
  }
}

apply plugin: 'io.spring.convention.root'

allprojects {

  group = 'org.springframework.data'

  repositories {

    mavenCentral()

    if (version.contains('-')) {
      maven { url "https://repo.spring.io/milestone" }
    }
    if (version.endsWith('-SNAPSHOT')) {
      maven { url "https://repo.spring.io/snapshot" }
    }
  }

  configurations.all {
    resolutionStrategy.cacheChangingModulesFor 0, "minutes"
  }
}

description = 'Spring Test Framework for Apache Geode and VMware Tanzu GemFire using Spring Data.'

//ext['spring.version'] = "$springVersion"
ext['spring-framework.version'] = "$springVersion"
ext['spring-data-bom.version'] = "$springDataBomVersion"

ext.releaseBuild = version.endsWith('RELEASE')
ext.snapshotBuild = version.endsWith('SNAPSHOT')
ext.milestoneBuild = !(releaseBuild || snapshotBuild)

ext.MAVEN_POM_EDITOR_GRADLE = "$rootDir/gradle/maven-pom-editor.gradle"

project.checkstyle.sourceSets.forEach { it -> it.excludes '**/target', '**/out', '**/build' }

//project.tasks.findByName('checkstyleNohttp').configure {
//	exclude '**/target/**/*', '**/out/**/*', '**/build/**/*'
//}

tasks.withType(Checkstyle) {
  exclude '**/target/**/*', '**/out/**/*', '**/build/**/*'
}