[Messaging] Generates tests on the server side

WIP on #234

samples/messaging-integration/src/main/groovy/io/codearte/accurest/samples/messaging/BookDeleted.groovy

@@ -0,0 +1,14 @@
+package io.codearte.accurest.samples.messaging
+
+import com.fasterxml.jackson.annotation.JsonCreator
+import groovy.transform.CompileStatic
+
+@CompileStatic
+class BookDeleted {
+	final String bookName
+
+	@JsonCreator(mode = JsonCreator.Mode.PROPERTIES)
+	BookDeleted(String bookName) {
+		this.bookName = bookName
+	}
+}

samples/messaging-integration/src/main/groovy/io/codearte/accurest/samples/messaging/BookListener.groovy

@@ -0,0 +1,38 @@
+package io.codearte.accurest.samples.messaging
+
+import groovy.transform.CompileStatic
+import groovy.util.logging.Slf4j
+import org.springframework.messaging.Message
+import org.springframework.messaging.MessageHeaders
+import org.springframework.messaging.support.MessageBuilder
+
+import java.util.concurrent.atomic.AtomicBoolean
+
+@CompileStatic
+@Slf4j
+class BookListener {
+
+	/**
+	   Scenario for "should generate tests triggered by a message":
+	     client side: if sends a message to input.messageFrom then message will be sent to output.messageFrom
+	     server side: will send a message to input, verify the message contents and await upon receiving message on the output messageFrom
+	 */
+	Message returnBook(BookReturned bookReturned) {
+		log.info("Returning book [$bookReturned]")
+		return MessageBuilder.createMessage(bookReturned, new MessageHeaders([
+		        'BOOK-NAME': bookReturned.bookName as Object
+		]))
+	}
+
+	/**
+	   Scenario for "should generate tests triggered by a message":
+	     client side: if sends a message to input.messageFrom then message will be sent to output.messageFrom
+	     server side: will send a message to input, verify the message contents and await upon receiving message on the output messageFrom
+	 */
+	void bookDeleted(BookDeleted bookDeleted) {
+		log.info("Deleting book [$bookDeleted]")
+		bookSuccessfulyDeleted.set(true)
+	}
+
+	AtomicBoolean bookSuccessfulyDeleted = new AtomicBoolean(false)
+}

samples/messaging-integration/src/main/groovy/io/codearte/accurest/samples/messaging/BookReturned.groovy

@@ -0,0 +1,14 @@
+package io.codearte.accurest.samples.messaging
+
+import com.fasterxml.jackson.annotation.JsonCreator
+import groovy.transform.CompileStatic
+
+@CompileStatic
+class BookReturned {
+	final String bookName
+
+	@JsonCreator(mode = JsonCreator.Mode.PROPERTIES)
+	BookReturned(String bookName) {
+		this.bookName = bookName
+	}
+}

samples/messaging-integration/src/main/groovy/io/codearte/accurest/samples/messaging/BookService.groovy

@@ -0,0 +1,32 @@
+package io.codearte.accurest.samples.messaging
+
+import groovy.transform.CompileStatic
+import groovy.util.logging.Slf4j
+import org.springframework.beans.factory.annotation.Autowired
+import org.springframework.beans.factory.annotation.Qualifier
+import org.springframework.messaging.MessageChannel
+import org.springframework.messaging.MessageHeaders
+import org.springframework.messaging.support.MessageBuilder
+import org.springframework.stereotype.Service
+
+@Service
+@CompileStatic
+@Slf4j
+class BookService {
+
+	@Autowired @Qualifier("outputChannel") MessageChannel outputChannel
+
+	/**
+	   Scenario for "should generate tests triggered by a method":
+	      client side: must have a possibility to "trigger" sending of a message to the given messageFrom
+	      server side: will run the method and await upon receiving message on the output messageFrom
+
+	   Method triggers sending a message to a source
+	 */
+	void returnBook(BookReturned bookReturned) {
+		log.info("Returning book [$bookReturned]")
+		outputChannel.send(MessageBuilder.createMessage(bookReturned, new MessageHeaders([
+		        'BOOK-NAME': bookReturned.bookName as Object
+		])))
+	}
+}

samples/messaging-integration/src/main/groovy/io/codearte/accurest/samples/messaging/IntegrationMessagingApplication.groovy

@@ -0,0 +1,14 @@
+package io.codearte.accurest.samples.messaging
+
+import org.springframework.boot.SpringApplication
+import org.springframework.boot.autoconfigure.SpringBootApplication
+import org.springframework.context.annotation.ImportResource
+
+@SpringBootApplication
+@ImportResource("classpath*:integration-context.xml")
+class IntegrationMessagingApplication {
+
+	static void main(String[] args) {
+		SpringApplication.run(IntegrationMessagingApplication.class, args)
+	}
+}

samples/messaging-integration/src/main/resources/integration-context.xml

@@ -0,0 +1,40 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<beans:beans xmlns="http://www.springframework.org/schema/integration"
+			 xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
+			 xmlns:beans="http://www.springframework.org/schema/beans"
+			 xsi:schemaLocation="http://www.springframework.org/schema/beans
+			http://www.springframework.org/schema/beans/spring-beans.xsd
+			http://www.springframework.org/schema/integration
+			http://www.springframework.org/schema/integration/spring-integration.xsd">
+
+	<channel id="input"/>
+	<channel id="delete"/>
+	<channel id="outputChannel"/>
+
+	<service-activator input-channel="inputChannel"
+					   output-channel="outputChannel"
+					   ref="bookListener"
+					   method="returnBook"/>
+
+	<json-to-object-transformer input-channel="input" type="io.codearte.accurest.samples.messaging.BookReturned"
+	output-channel="inputChannel"/>
+
+	<service-activator input-channel="deleteChannel"
+					   ref="bookListener"
+					   method="bookDeleted"/>
+
+	<json-to-object-transformer input-channel="delete" type="io.codearte.accurest.samples.messaging.BookDeleted"
+								output-channel="deleteChannel"/>
+
+	<beans:bean id="bookListener" class="io.codearte.accurest.samples.messaging.BookListener"/>
+
+
+	<!-- REQUIRED FOR TESTING -->
+	<bridge input-channel="outputChannel"
+			output-channel="output"/>
+
+	<channel id="output">
+		<queue/>
+	</channel>
+
+</beans:beans>

samples/messaging-integration/src/test/groovy/io/codearte/accurest/samples/messaging/IntegrationMessagingApplicationSpec.groovy

@@ -0,0 +1,138 @@
+package io.codearte.accurest.samples.messaging
+
+import com.fasterxml.jackson.databind.ObjectMapper
+import com.jayway.jsonpath.DocumentContext
+import com.jayway.jsonpath.JsonPath
+import com.toomuchcoding.jsonassert.JsonAssertion
+import io.codearte.accurest.dsl.GroovyDsl
+import io.codearte.accurest.messaging.AccurestMessage
+import io.codearte.accurest.messaging.AccurestMessaging
+import org.springframework.beans.factory.annotation.Autowired
+import org.springframework.boot.test.SpringApplicationContextLoader
+import org.springframework.test.context.ContextConfiguration
+import spock.lang.Specification
+
+import javax.inject.Inject
+
+/**
+ * SPIKE ON TESTS FROM NOTES IN MessagingSpec
+ */
+// Context configuration would end up in base class
+@ContextConfiguration(classes = [IntegrationMessagingApplication], loader = SpringApplicationContextLoader)
+public class IntegrationMessagingApplicationSpec extends Specification {
+
+	// ALL CASES
+	@Inject AccurestMessaging accurestMessaging
+	ObjectMapper accurestObjectMapper = new ObjectMapper()
+
+	def "should work for triggered based messaging"() {
+		given:
+			def dsl = GroovyDsl.make {
+				label 'some_label'
+				input {
+					triggeredBy('bookReturnedTriggered()')
+				}
+				outputMessage {
+					sentTo('output')
+					body('''{ "bookName" : "foo" }''')
+					headers {
+						header('BOOK-NAME', 'foo')
+					}
+				}
+			}
+		// generated test should look like this:
+		when:
+			bookReturnedTriggered()
+		then:
+			def response = accurestMessaging.receiveMessage('output')
+			response.headers.get('BOOK-NAME')  == 'foo'
+		and:
+			DocumentContext parsedJson = JsonPath.parse(accurestObjectMapper.writeValueAsString(response.payload))
+			JsonAssertion.assertThat(parsedJson).field('bookName').isEqualTo('foo')
+	}
+
+	def "should generate tests triggered by a message"() {
+		given:
+			def dsl = GroovyDsl.make {
+				label 'some_label'
+				input {
+					messageFrom('input')
+					messageBody([
+					        bookName: 'foo'
+					])
+					messageHeaders {
+						header('sample', 'header')
+					}
+				}
+				outputMessage {
+					sentTo('output')
+					body([
+					        bookName: 'foo'
+					])
+					headers {
+						header('BOOK-NAME', 'foo')
+					}
+				}
+			}
+
+		// generated test should look like this:
+
+		//given:
+		AccurestMessage inputMessage = accurestMessaging.create(
+				accurestObjectMapper.writeValueAsString([bookName: 'foo']),
+				[sample: 'header']
+		)
+		when:
+			accurestMessaging.send(inputMessage, 'input')
+		then:
+			def response = accurestMessaging.receiveMessage('output')
+			response.headers.get('BOOK-NAME')  == 'foo'
+		and:
+			DocumentContext parsedJson = JsonPath.parse(accurestObjectMapper.writeValueAsString(response.payload))
+			JsonAssertion.assertThat(parsedJson).field('bookName').isEqualTo('foo')
+	}
+
+	def "should generate tests without destination, triggered by a message"() {
+		given:
+			def dsl = GroovyDsl.make {
+				label 'some_label'
+				input {
+					messageFrom('delete')
+					messageBody([
+					        bookName: 'foo'
+					])
+					messageHeaders {
+						header('sample', 'header')
+					}
+					assertThat('bookWasDeleted()')
+				}
+			}
+
+		// generated test should look like this:
+
+		//given:
+		AccurestMessage inputMessage = accurestMessaging.create(
+				accurestObjectMapper.writeValueAsString([bookName: 'foo']),
+				[sample: 'header']
+		)
+		when:
+			accurestMessaging.send(inputMessage, 'delete')
+		then:
+			noExceptionThrown()
+			bookWasDeleted()
+	}
+
+	// BASE CLASS WOULD HAVE THIS:
+
+	@Autowired BookService bookService
+	@Autowired BookListener bookListener
+
+	void bookReturnedTriggered() {
+		bookService.returnBook(new BookReturned("foo"))
+	}
+
+	void bookWasDeleted() {
+		assert bookListener.bookSuccessfulyDeleted.get()
+	}
+
+}