pluginManagement {
    repositories {
        gradlePluginPortal()
        mavenCentral()
    }
}

plugins {
    id 'io.spring.develocity.conventions' version '0.0.23' apply false
}

startParameter.noBuildScan = startParameter.taskNames.contains('format')

apply plugin: 'io.spring.develocity.conventions'

rootProject.name = 'spring-functions-catalog'

include 'spring-functions-catalog-bom'

['common', 'consumer', 'function', 'supplier'].each { group ->
    def groupDir = file(group)
    groupDir.eachDir { subProject ->
        include "${subProject.name}"
        project(":${subProject.name}").projectDir = new File(groupDir.absolutePath, subProject.name)
    }
}
